アセンブリ言語プログラムの BNF 風表現

KUECHIP-3F アセンブラが入力として扱うことができるアセンブリ言語プログラムの BNF 風表現を以下に示す.

<program>                  ::= <instruction>+
<instruction>              ::= [<label>{<space> | <newline>}+] <0op inst> [<comment>] <newline>+
                             | [<label>{<space> | <newline>}+] <1op inst> [<comment>] <newline>+
                             | [<label>{<space> | <newline>}+] <2op inst> [<comment>] <newline>+
<label>                    ::= <alphanumeric character>+ ':'
<alphanumeric character>   ::= 'A' | 'B' | ... | 'Z' | 'a' | ... | 'z' | '0' | ... | '9'
<0op inst>                 ::= <0op inst mnemonic>
<0op inst mnemonic>        ::= 'NOP' | 'RET' | 'HLT' | 'OUT' | 'IN' | 'RCF' | 'SCF'
<1op inst>                 ::= <1op inst mnemonic> <space> <operand>
<1op inst mnemonic>        ::= 'INC' | 'DEC' | 'CAL' | PSH' | 'POP'
                             | 'BA' | 'BNZ' | 'BZP' | 'BP' | 'BNI' | 'BNC' | 'BGE' | 'BGT'
                             | 'BVF' | 'BZ' | 'BN' | 'BZN' | 'BNO' | 'BC' | 'BLT' | 'BLE'
                             | 'SRA' | 'SLA' | 'SRL' | 'SLL' | 'RRA' | 'RLA' | 'RRL' | 'RLL'
<2op inst>                 ::= <2op inst mnemonic> <space> <operand> [','] <space> <operand>
<2op inst mnemonic>        ::= 'INC' | 'DEC' | 'LD' | 'ST' | 'SBC' | 'ADC' | 'SUB' | 'ADD'
                             | 'EOR' | 'OR' | 'AND' | 'CMP'
<comment>                  ::= '#' (任意の文字列)
<newline>                  ::= (LF) | (CR) (LF)
<operand>                  ::= <register>
                             | <immediate value>
                             | '[' <immediate value> ']'
                             | '[' <offsetted register value> ']'
<register>                 ::= 'ACC' | 'IX' | 'SP'
<immediate value>          ::= <expression>
<offsetted register value> ::= 'IX' <space>* '+' <space>* <immediate value>
                             | 'IX' <space>* '-' <space>* <immediate value>
                             | 'SP' <space>* '+' <space>* <immediate value>
                             | 'SP' <space>* '-' <space>* <immediate value>
<expression>               ::= <term>
                             | <expression> <space>* '+' <space>* <term>
                             | <expression> <space>* '-' <space>* <term>
<term>                     ::= <factor>
                             | <term> <space>* '*' <space>* <factor>
                             | <term> <space>* '/' <space>* <factor>
<factor>                   ::= <number> | <label>
<number>                   ::= <decimal number>+
                             | {<decimal character> | <alphabet in hex>}+ {'H' | 'h'}
<numerical character>      ::= '0' | '1' | ... | '9'
<alphabet in hex>          ::= 'A' | 'B' | ... | 'F' | 'a' | 'b' | ... | 'f'
<space>                    ::= ' ' | '	'

ここで用いている BNF 派生表現は下記の通りである. ただし, オペランドの制約は正確に示すと表現が複雑になりすぎるため上記の表現では考慮していない.
例えば, ST の第 2 オペランドにレジスタを指定することはできない.
各ニーモニックに対してどのようなオペランドを用いるかは, 別途ドキュメントを参照のこと.

• クオート付き文字列は文字列そのものを表す
• [] 付き要素は省略可能
• {} はアイテムのグループのうち任意の 1 つを表す
• * は 0 個以上の繰り返しを表す
• + は 1 個以上の繰り返しを表す

各要素について

N:    EQU      80H      |
SUM:  EQU      82H      |
      LOC      80H      |
      DAT      AH       |    0080: 000A
      LD  IX,  [N]      |    0000: 006C 0080
      LD  ACC, 0        |    0004: 0062 0000
LOOP: ADD ACC, IX       |    0008: 00B1
      SUB IX,  1        |    000A: 00AA 0001
      BP       LOOP     |    000E: 0033 0008
      ST  ACC, [SUM]    |    0012: 0074 0082
      HLT               |    0016: 000F